Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 AC_INIT([GNU tar], [1.15.2], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([build-aux])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_PROG_YACC
  33 AC_SYS_LARGEFILE
  34 AC_ISC_POSIX
  35 AC_C_INLINE
  36
  37 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  38   sgtty.h string.h \
  39   sys/param.h sys/device.h sys/gentape.h \
  40   sys/inet.h sys/io/trioctl.h \
  41   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  42   unistd.h locale.h)
  43
  44 AC_CHECK_HEADERS([sys/buf.h], [], [],
  45 [#if HAVE_SYS_PARAM_H
  46 #include <sys/param.h>
  47 #endif])
  48
  49 AC_HEADER_SYS_WAIT
  50 AM_STDBOOL_H
  51
  52 AC_HEADER_DIRENT
  53 AC_HEADER_MAJOR
  54 AC_HEADER_STAT
  55 AC_HEADER_STDC
  56 AC_STRUCT_ST_BLKSIZE
  57 AC_STRUCT_ST_BLOCKS
  58 AC_MSG_CHECKING([for st_fstype string in struct stat])
  59 AC_CACHE_VAL(diff_cv_st_fstype_string,
  60   [AC_TRY_COMPILE([#include <sys/types.h>
  61 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  62    diff_cv_st_fstype_string=yes,
  63    diff_cv_st_fstype_string=no)])
  64 AC_MSG_RESULT($diff_cv_st_fstype_string)
  65 if test $diff_cv_st_fstype_string = yes; then
  66   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  67     [Define if struct stat has a char st_fstype[] member.])
  68 fi
  69
  70 AC_TYPE_SIGNAL
  71 AC_TYPE_MODE_T
  72 AC_TYPE_PID_T
  73 AC_TYPE_OFF_T
  74 AC_TYPE_SIZE_T
  75 AC_TYPE_UID_T
  76 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  77                                    [Type of major device numbers.]))
  78 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  79                                    [Type of minor device numbers.]))
  80 AC_CHECK_TYPE(dev_t, unsigned)
  81 AC_CHECK_TYPE(ino_t, unsigned)
  82
  83 gt_TYPE_SSIZE_T
  84 gl_AC_TYPE_INTMAX_T
  85 jm_AC_TYPE_UINTMAX_T
  86
  87 # gnulib modules
  88 tar_GNULIB
  89 # paxutils modules
  90 tar_PAXUTILS
  91
  92 AC_CHECK_MEMBERS([struct stat.st_spare1, struct stat.st_atim.tv_nsec, struct stat.st_atimespec.tv_nsec, struct stat.st_atimensec], , ,
  93                  [
  94 #include <sys/types.h>
  95 #include <sys/stat.h>])
  96
  97 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
  98 # programs in the package would end up linked with that potentially-shared
  99 # library, inducing unnecessary run-time overhead.
 100
 101 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 102 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 103 tar_save_LIBS=$LIBS
 104   LIB_CLOCK_GETTIME=
 105   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 106   case "$ac_cv_search_clock_gettime" in
 107     -l*) LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime;;
 108   esac
 109   AC_SUBST(LIB_CLOCK_GETTIME)
 110   AC_CHECK_FUNCS(clock_gettime)
 111 LIBS=$tar_save_LIBS
 112
 113 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
 114 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 115 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 116 AC_CHECK_DECLS([time],,, [#include <time.h>])
 117
 118 AC_REPLACE_FUNCS(waitpid)
 119
 120 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 121   [if test -n "$RSH"; then
 122     tar_cv_path_RSH=$RSH
 123   else
 124     tar_cv_path_RSH=no
 125     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 126         /usr/bin/nsh /usr/bin/rcmd
 127     do
 128       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 129       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 130       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 131       if test -f $ac_file; then
 132         if (test -h $ac_file) 2>/dev/null; then
 133           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 134         else
 135           tar_cv_path_RSH=$ac_file
 136           break
 137         fi
 138       fi
 139     done
 140   fi])
 141 if test $tar_cv_path_RSH = no; then
 142   AC_CHECK_HEADERS(netdb.h)
 143 else
 144   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 145     [Define to the full path of your rsh, if any.])
 146 fi
 147
 148 AC_MSG_CHECKING(for default archive format)
 149
 150 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 151            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 152
 153 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 154   DEFAULT_ARCHIVE_FORMAT="GNU"
 155 fi
 156 case $DEFAULT_ARCHIVE_FORMAT in
 157   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 158   *) AC_MSG_ERROR(Invalid format name);;
 159 esac
 160 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 161   [By default produce archives of this format])
 162 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 163
 164 AC_MSG_CHECKING(for default archive)
 165
 166 AC_ARG_VAR([DEFAULT_ARCHIVE],
 167            [Set the name of the default archive (default: -)])
 168 if test -z "$DEFAULT_ARCHIVE"; then
 169   DEFAULT_ARCHIVE=-
 170 else
 171   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 172     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 173   fi
 174   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 175   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 176   # FIXME: Rearrange, here.
 177   case $DEFAULT_ARCHIVE in
 178     *[[0-7][lmh]])
 179       AC_DEFINE(DENSITY_LETTER, 1,
 180         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 181       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 182       ;;
 183     *[[0-7]])
 184       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 185       ;;
 186     *)
 187       device_prefix=
 188       ;;
 189   esac
 190   case "$device_prefix" in
 191     ?*)
 192       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 193         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 194       ;;
 195   esac
 196 fi
 197 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 198   [Define to a string giving the full name of the default archive file.])
 199 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 200
 201 AC_ARG_VAR([DEFAULT_BLOCKING],
 202            [Define default blocking factor (default: 20)])
 203 AC_MSG_CHECKING(for default blocking)
 204 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 205 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 206   [Define to a number giving the default blocking size for archives.])
 207 AC_MSG_RESULT($DEFAULT_BLOCKING)
 208
 209 # Iconv
 210 AM_ICONV
 211 AC_CHECK_HEADERS(iconv.h)
 212 AC_CHECK_TYPE(iconv_t,:,
 213               AC_DEFINE(iconv_t, int,
 214                         [Conversion descriptor type]),
 215               [
 216 #ifdef HAVE_ICONV_H
 217 # include <iconv.h>
 218 #endif
 219 ])
 220
 221 # Gettext.
 222 AM_GNU_GETTEXT([external], [need-ngettext])
 223 AM_GNU_GETTEXT_VERSION(0.12.1)
 224
 225 # Initialize the test suite.
 226 AC_CONFIG_TESTDIR(tests)
 227 AC_CONFIG_FILES([tests/Makefile tests/atlocal]) # FIXME: tests/preset?
 228 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 229
 230 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 231 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 232 AC_ARG_ENABLE(backup-scripts,
 233               AC_HELP_STRING([--enable-backup-scripts],
 234                              [Create and install backup and restore scripts]),
 235               [case $enableval in
 236                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 237                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 238                     ;;
 239                esac])
 240
 241 AC_SUBST(BACKUP_SED_COND)
 242 if date +%Y-%m-%d 2>/dev/null >&2; then
 243         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 244 else
 245         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 246 fi
 247
 248
 249 AC_OUTPUT([Makefile\
 250            doc/Makefile\
 251            lib/Makefile\
 252            po/Makefile.in\
 253            scripts/Makefile\
 254            rmt/Makefile\
 255            src/Makefile])