Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003, 2004 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_INIT([GNU tar], [1.14.1], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([config])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.59])
  26 AM_INIT_AUTOMAKE([1.8 gnits dist-bzip2 dist-shar std-options])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_PROG_YACC
  33 AC_SYS_LARGEFILE
  34 AC_ISC_POSIX
  35 AC_C_INLINE
  36
  37 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  38   sgtty.h string.h \
  39   sys/param.h sys/device.h sys/gentape.h \
  40   sys/inet.h sys/io/trioctl.h \
  41   sys/mtio.h sys/time.h sys/tprintf.h sys/tape.h \
  42   unistd.h)
  43
  44 AC_CHECK_HEADERS([sys/buf.h], [], [],
  45 [#if HAVE_SYS_PARAM_H
  46 #include <sys/param.h>
  47 #endif])
  48
  49 AC_HEADER_SYS_WAIT
  50 AM_STDBOOL_H
  51
  52 if test $ac_cv_header_sys_mtio_h = yes; then
  53   AC_CACHE_CHECK(for remote tape header files, tar_cv_header_rmt,
  54     [AC_TRY_CPP([
  55 #if HAVE_SGTTY_H
  56 # include <sgtty.h>
  57 #endif
  58 #include <sys/socket.h>],
  59     tar_cv_header_rmt=yes, tar_cv_header_rmt=no)])
  60   test $tar_cv_header_rmt = yes && RMT='rmt$(EXEEXT)'
  61   AC_SUBST(RMT)
  62 fi
  63
  64 AC_CACHE_CHECK(which ioctl field to test for reversed bytes,
  65   tar_cv_header_mtio_check_field,
  66   [AC_EGREP_HEADER(mt_model, sys/mtio.h,
  67   tar_cv_header_mtio_check_field=mt_model,
  68   tar_cv_header_mtio_check_field=mt_type)])
  69 AC_DEFINE_UNQUOTED(MTIO_CHECK_FIELD, $tar_cv_header_mtio_check_field,
  70   [Define to mt_model (v.g., for DG/UX), else to mt_type.])
  71
  72 AC_HEADER_DIRENT
  73 AC_HEADER_MAJOR
  74 AC_HEADER_STAT
  75 AC_HEADER_STDC
  76 AC_STRUCT_ST_BLKSIZE
  77 AC_STRUCT_ST_BLOCKS
  78 AC_MSG_CHECKING([for st_fstype string in struct stat])
  79 AC_CACHE_VAL(diff_cv_st_fstype_string,
  80   [AC_TRY_COMPILE([#include <sys/types.h>
  81 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  82    diff_cv_st_fstype_string=yes,
  83    diff_cv_st_fstype_string=no)])
  84 AC_MSG_RESULT($diff_cv_st_fstype_string)
  85 if test $diff_cv_st_fstype_string = yes; then
  86   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  87     [Define if struct stat has a char st_fstype[] member.])
  88 fi
  89
  90 AC_TYPE_SIGNAL
  91 AC_TYPE_MODE_T
  92 AC_TYPE_PID_T
  93 AC_TYPE_OFF_T
  94 AC_TYPE_SIZE_T
  95 AC_TYPE_UID_T
  96 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  97                                    [Type of major device numbers.]))
  98 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  99                                    [Type of minor device numbers.]))
 100 AC_CHECK_TYPE(dev_t, unsigned)
 101 AC_CHECK_TYPE(ino_t, unsigned)
 102
 103 gt_TYPE_SSIZE_T
 104 gl_AC_TYPE_INTMAX_T
 105 jm_AC_TYPE_UINTMAX_T
 106
 107 # gnulib modules
 108 tar_GNULIB
 109
 110
 111 AC_CHECK_MEMBERS([struct stat.st_spare1, struct stat.st_atim.tv_nsec, struct stat.st_atimespec.tv_nsec, struct stat.st_atimensec], , ,
 112                  [
 113 #include <sys/types.h>
 114 #include <sys/stat.h>])
 115
 116 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
 117 # programs in the package would end up linked with that potentially-shared
 118 # library, inducing unnecessary run-time overhead.
 119
 120 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 121 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 122 tar_save_LIBS=$LIBS
 123   LIB_CLOCK_GETTIME=
 124   AC_SEARCH_LIBS(clock_gettime, [rt posix4])
 125   case "$ac_cv_search_clock_gettime" in
 126     -l*) LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime;;
 127   esac
 128   AC_SUBST(LIB_CLOCK_GETTIME)
 129   AC_CHECK_FUNCS(clock_gettime)
 130 LIBS=$tar_save_LIBS
 131
 132 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink setlocale utimes)
 133 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 134 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 135 AC_CHECK_DECLS([valloc])
 136 AC_CHECK_DECLS([time],,, [#include <time.h>])
 137
 138 # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
 139 tar_save_LIBS=$LIBS
 140   LIB_SETSOCKOPT=
 141   AC_SEARCH_LIBS(setsockopt, [socket], ,
 142     [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
 143   AC_SEARCH_LIBS(setsockopt, [nsl])
 144
 145   case "$ac_cv_search_setsockopt" in
 146     -l*) LIB_SETSOCKOPT=$ac_cv_search_setsockopt
 147   esac
 148   AC_SUBST(LIB_SETSOCKOPT)
 149 LIBS=$tar_save_LIBS
 150
 151 AC_REPLACE_FUNCS(waitpid)
 152
 153 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 154   [if test -n "$RSH"; then
 155     tar_cv_path_RSH=$RSH
 156   else
 157     tar_cv_path_RSH=no
 158     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 159         /usr/bin/nsh /usr/bin/rcmd
 160     do
 161       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 162       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 163       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 164       if test -f $ac_file; then
 165         if (test -h $ac_file) 2>/dev/null; then
 166           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 167         else
 168           tar_cv_path_RSH=$ac_file
 169           break
 170         fi
 171       fi
 172     done
 173   fi])
 174 if test $tar_cv_path_RSH = no; then
 175   AC_CHECK_HEADERS(netdb.h)
 176 else
 177   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 178     [Define to the full path of your rsh, if any.])
 179 fi
 180
 181 AC_MSG_CHECKING(for default archive format)
 182
 183 AC_ARG_VAR([DEFAULT_ARCHIVE_FORMAT],
 184            [Set the default archive format. Allowed values are: V7, OLDGNU, USTAR, POSIX, GNU. Default is GNU])
 185
 186 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 187   DEFAULT_ARCHIVE_FORMAT="GNU"
 188 fi
 189 case $DEFAULT_ARCHIVE_FORMAT in
 190   V7|OLDGNU|USTAR|POSIX|GNU) ;;
 191   *) AC_MSG_ERROR(Invalid format name);;
 192 esac
 193 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 194   [By default produce archives of this format])
 195 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 196
 197 AC_MSG_CHECKING(for default archive)
 198
 199 AC_ARG_VAR([DEFAULT_ARCHIVE],
 200            [Set the name of the default archive (default: -)])
 201 if test -z "$DEFAULT_ARCHIVE"; then
 202   DEFAULT_ARCHIVE=-
 203 else
 204   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 205     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 206   fi
 207   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 208   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 209   # FIXME: Rearrange, here.
 210   case $DEFAULT_ARCHIVE in
 211     *[[0-7][lmh]])
 212       AC_DEFINE(DENSITY_LETTER, 1,
 213         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 214       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 215       ;;
 216     *[[0-7]])
 217       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 218       ;;
 219     *)
 220       device_prefix=
 221       ;;
 222   esac
 223   case "$device_prefix" in
 224     ?*)
 225       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 226         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 227       ;;
 228   esac
 229 fi
 230 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 231   [Define to a string giving the full name of the default archive file.])
 232 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 233
 234 AC_ARG_VAR([DEFAULT_BLOCKING],
 235            [Define default blocking factor (default: 20)])
 236 AC_MSG_CHECKING(for default blocking)
 237 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 238 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 239   [Define to a number giving the default blocking size for archives.])
 240 AC_MSG_RESULT($DEFAULT_BLOCKING)
 241
 242 AC_ARG_VAR([DEFAULT_RMT_COMMAND],
 243            [Define full pathname of rmt program.])
 244 if test "x$DEFAULT_RMT_COMMAND" != x; then
 245   AC_DEFINE_UNQUOTED(DEFAULT_RMT_COMMAND, "$DEFAULT_RMT_COMMAND",
 246                      [Define full pathname of rmt program.])
 247 fi
 248
 249 # Gettext.
 250 AM_GNU_GETTEXT([external], [need-ngettext])
 251 AM_GNU_GETTEXT_VERSION(0.12.1)
 252
 253 # Iconv
 254 AM_ICONV
 255 AC_CHECK_HEADERS(iconv.h)
 256 AC_CHECK_TYPE(iconv_t,:,
 257               AC_DEFINE(iconv_t, int,
 258                         [Conversion descriptor type]),
 259               [
 260 #ifdef HAVE_ICONV_H
 261 # include <iconv.h>
 262 #endif
 263 ])
 264
 265 AC_SUBST(BACKUP_LIBEXEC_SCRIPTS)
 266 AC_SUBST(BACKUP_SBIN_SCRIPTS)
 267 AC_ARG_ENABLE(backup-scripts,
 268               AC_HELP_STRING([--enable-backup-scripts],
 269                              [Create and install backup and restore scripts]),
 270               [case $enableval in
 271                yes) BACKUP_LIBEXEC_SCRIPTS='$(BACKUP_LIBEXEC_SCRIPTS_LIST)'
 272                     BACKUP_SBIN_SCRIPTS='$(BACKUP_SBIN_SCRIPTS_LIST)'
 273                     ;;
 274                esac])
 275
 276 AC_SUBST(BACKUP_SED_COND)
 277 if date +%Y-%m-%d 2>/dev/null >&2; then
 278         BACKUP_SED_COND='/^\#ELSE_DATE_FORMAT_OK/,/^\#ENDIF_DATE_FORMAT_OK/d;/^\#IF_DATE_FORMAT_OK/d'
 279 else
 280         BACKUP_SED_COND='/^\#IF_DATE_FORMAT_OK/,/^\#ELSE_DATE_FORMAT_OK/d;/^\#ENDIF_DATE_FORMAT_OK/d'
 281 fi
 282
 283
 284 AC_OUTPUT([Makefile\
 285            doc/Makefile\
 286            lib/Makefile\
 287            po/Makefile.in\
 288            scripts/Makefile\
 289            src/Makefile\
 290            tests/Makefile\
 291            tests/preset])