Dogcows Code - chaz/yoink/blob - configure.ac

   1
   2 #
   3 # Yoink
   4 # Process this file with autoconf to produce a configure script.
   5 #
   6
   7 AC_PREREQ([2.60])
   8
   9 AC_INIT([Yoink], [0.1], [chaz@dogcows.com], [yoink])
  10
  11 AC_CANONICAL_TARGET
  12
  13 AC_CONFIG_SRCDIR([src/GameLayer.cc])
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 AM_INIT_AUTOMAKE
  17
  18
  19 #
  20 # Checks for programs.
  21 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  22
  23 AC_PROG_CXX
  24 AC_PROG_CC
  25 AC_PROG_CPP
  26 AC_PROG_INSTALL
  27 AC_PROG_RANLIB
  28 AM_PROG_CC_C_O
  29
  30
  31 #
  32 # Configure platform-specific stuff.
  33 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  34
  35 case "${host}" in
  36         *mingw32*)
  37                 MINGW32=yes
  38                 WIN32=yes
  39                 AC_PATH_PROGS([WINDRES], [windres $host_alias-windres $host_os-windres])
  40                 if test "x$WINDRES" = x
  41                 then
  42                         AC_MSG_ERROR([windres could not be found])
  43                 fi
  44                 AC_SUBST(WINDRES)
  45                 AC_PATH_PROGS([MAKENSIS], [makensis])
  46                 AC_SUBST(MAKENSIS)
  47         ;;
  48         *cygwin*)
  49                 CYGWIN=yes
  50                 WIN32=yes
  51         ;;
  52         *-apple-darwin*)
  53                 MACOSX=yes
  54                 LIBS="$LIBS -Wl,-framework"
  55         ;;
  56         *-linux-gnu*)
  57                 LINUX=yes
  58                 AC_PATH_PROGS([RPMBUILD], [rpmbuild])
  59                 AC_SUBST(RPMBUILD)
  60         ;;
  61 esac
  62
  63 AM_CONDITIONAL([LINUX], test "$LINUX" = "yes")
  64 AM_CONDITIONAL([WIN32], test "$WIN32" = "yes")
  65
  66
  67 #
  68 # Checks for configuration arguments.
  69 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
  70
  71 AC_ARG_ENABLE([developer],
  72                           [  --enable-developer      use all compiler flags developers need],
  73                           [developer=$enableval],
  74                           [developer=no])
  75
  76 AC_ARG_ENABLE([debug],
  77                           [  --enable-debug          include debugging symbols and features],
  78                           [debug=$enableval],
  79                           [debug=no])
  80
  81 AC_ARG_ENABLE([profile],
  82                           [  --enable-profile        make a binary for use with gprof profiler],
  83                           [profile=$enableval],
  84                           [profile=no])
  85
  86 AC_ARG_ENABLE([extra-warnings],
  87                           [  --enable-extra-warnings make the gcc compiler give more warnings],
  88                           [extra_warnings=$enableval],
  89                           [extra_warnings=no])
  90
  91 AC_ARG_WITH([log-level],
  92                         [AS_HELP_STRING([--with-log-level=NUM],
  93                                                         [0, none... 1, errors... 4, everything (default: 3)])],
  94                         [log_level=$withval],
  95                         [log_level=3])
  96
  97 AC_ARG_ENABLE([double],
  98                           [  --enable-double         use double-precision numbers],
  99                           [double=$enableval],
 100                           [double=no])
 101
 102
 103 if test x$developer = xyes
 104 then
 105         debug=yes
 106         log_level=4
 107
 108         if test x$WIN32 != xyes
 109         then
 110 # i haven't had much success with gprof profiling on win32
 111                 profile=yes
 112         fi
 113 fi
 114
 115 if test x$debug = xyes
 116 then
 117         CFLAGS="$CFLAGS -Wall -O0 -DDEBUG"
 118         CXXFLAGS="$CXXFLAGS -Wall -O0 -DDEBUG"
 119 else
 120         CFLAGS="$CFLAGS -O2 -DNDEBUG"
 121         CXXFLAGS="$CXXFLAGS -O2 -DNDEBUG"
 122 fi
 123
 124 if test x$profile = xyes
 125 then
 126         CFLAGS="$CFLAGS -pg"
 127         CXXFLAGS="$CXXFLAGS -pg"
 128 fi
 129
 130 if test x$extra_warnings = xyes
 131 then
 132         CFLAGS="$CFLAGS -Wextra -Wno-unused-parameter"
 133         CXXFLAGS="$CXXFLAGS -Wextra -Wno-unused-parameter"
 134 fi
 135
 136 if test x$double = xyes
 137 then
 138         AC_DEFINE([USE_DOUBLE_PRECISION], 1,
 139                           [Define to 1 if you want to use double-precison numbers.])
 140 fi
 141
 142
 143 AC_DEFINE_UNQUOTED([YOINK_LOGLEVEL], [$log_level],
 144                                    [Define to detail level of logging.])
 145
 146
 147 if test "x$prefix" = xNONE
 148 then
 149         prefix="$ac_default_prefix"
 150 fi
 151
 152 AC_ARG_WITH([assetdir],
 153                         [AS_HELP_STRING([--with-assetdir=DIR],
 154                                                         [real path to assets (default: $datarootdir/yoink)])],
 155                         [DATADIR="$withval"],
 156                         [eval DATADIR="$datarootdir/yoink"])
 157
 158 if test x$WIN32 = xyes
 159 then
 160         DATADIR="data"
 161 fi
 162
 163 AC_SUBST([DATADIR])
 164 AC_DEFINE_UNQUOTED([YOINK_DATADIR], ["$DATADIR"],
 165                                    [Define to path of game asset directory.])
 166
 167
 168 #
 169 # Split the version number into components.
 170 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 171
 172 VERSION_MAJOR=$(echo $VERSION | cut -d. -f1)
 173 VERSION_MINOR=$(echo $VERSION | cut -d. -f2)
 174 VERSION_REVISION=$(echo $VERSION | cut -d. -f3)
 175
 176 AC_DEFINE_UNQUOTED([VERSION_MAJOR], [${VERSION_MAJOR:-0}],
 177                                    [Define to major version number component.])
 178
 179 AC_DEFINE_UNQUOTED([VERSION_MINOR], [${VERSION_MINOR:-0}],
 180                                    [Define to minor version number component.])
 181
 182 AC_DEFINE_UNQUOTED([VERSION_REVISION], [${VERSION_REVISION:-0}],
 183                                    [Define to revision version number component.])
 184
 185 if test x$WIN32 = xyes
 186 then
 187         PVERSION="${VERSION_MAJOR:-0}.${VERSION_MINOR:-0}.${VERSION_REVISION:-0}.0"
 188         AC_SUBST([PVERSION])
 189 fi
 190
 191 # these are used in src/yoink.rc
 192
 193
 194 #
 195 # Checks for system functions/headers and compiler characteristics.
 196 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 197
 198 AC_C_STRINGIZE
 199 AC_C_INLINE
 200
 201 AC_TYPE_UINT8_T
 202 AC_TYPE_UINT16_T
 203 AC_TYPE_UINT32_T
 204 AC_TYPE_SIZE_T
 205 AC_TYPE_SSIZE_T
 206
 207 AC_FUNC_ERROR_AT_LINE
 208 AC_FUNC_STRTOD
 209 AC_CHECK_FUNCS([nanosleep strchr strcspn strrchr strstr])
 210
 211 AC_HEADER_STDBOOL
 212 AC_HEADER_STDC
 213 AC_CHECK_HEADERS([stddef.h stdint.h stdlib.h string.h unistd.h])
 214
 215
 216 #
 217 # Checks for build dependencies.
 218 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 219
 220 ##### boost #####
 221 website="http://www.boost.org/"
 222 BOOST_SMART_PTR
 223 BOOST_STRING_ALGO
 224 BOOST_BIND
 225 BOOST_FUNCTION
 226
 227 ##### SDL #####
 228 website="http://www.libsdl.org/"
 229 AM_PATH_SDL([1.2.10],
 230                         [CFLAGS="$CFLAGS $SDL_CFLAGS"
 231                          CXXFLAGS="$CXXFLAGS $SDL_CFLAGS"
 232                          LIBS="$LIBS $SDL_LIBS"])
 233
 234 ##### opengl, glu #####
 235 website="http://www.mesa3d.org/"
 236 AC_CHECK_HEADERS([GL/gl.h GL/glu.h],,
 237                                  [missing=yes
 238                                   echo "***** Missing GL headers ($website) *****"])
 239 if test x$WIN32 == xyes
 240 then
 241 # autoconf library search macro doesn't find opengl32 on windows because it uses
 242 # different name hashing, but it links fine; assume it's there
 243         LIBS="$LIBS -lglu32 -lopengl32"
 244 else
 245         AC_SEARCH_LIBS([glEnable], [GL MesaGL],,
 246                                    [missing=yes
 247                                         echo "***** Missing libGL ($website) *****"])
 248         AC_SEARCH_LIBS([gluDisk], [GLU MesaGLU],,
 249                                    [missing=yes
 250                                         echo "***** Missing libGLU ($website) *****"])
 251 fi
 252
 253 ##### openal, alut #####
 254 website="http://connect.creativelabs.com/openal/"
 255 AC_CHECK_HEADERS([AL/al.h AL/alut.h],,
 256                                  [missing=yes
 257                                   echo "***** Missing OpenAL headers ($website) *****"])
 258 AC_SEARCH_LIBS([alEnable], [openal openal32],,
 259                            [missing=yes
 260                                 echo "***** Missing libopenal ($website) *****"])
 261 AC_SEARCH_LIBS([alutInit], [alut],,
 262                            [missing=yes
 263                                 echo "***** Missing libalut ($website) *****"])
 264
 265 ##### SDL_image #####
 266 website="http://www.libsdl.org/projects/SDL_image/"
 267 AC_CHECK_HEADERS([SDL/SDL_image.h],,
 268                                  [missing=yes
 269                                   echo "***** Missing SDL_image header ($website) *****"])
 270 AC_SEARCH_LIBS([IMG_Load], [SDL_image],,
 271                            [missing=yes
 272                                 echo "***** Missing libSDL_image ($website) *****"])
 273
 274 ##### libvorbis #####
 275 website="http://www.xiph.org/downloads/"
 276 AC_CHECK_HEADERS([vorbis/codec.h vorbis/vorbisfile.h],,
 277                                  [missing=yes
 278                                   echo "***** Missing vorbis headers ($website) *****"])
 279 AC_SEARCH_LIBS([ov_open], [vorbisfile],,
 280                            [missing=yes
 281                                 echo "***** Missing libvorbisfile ($website) *****"])
 282
 283 ##### liblua #####
 284 website="http://www.lua.org/"
 285 AC_CHECK_HEADERS([lua.h],,
 286                                  [missing=yes
 287                                   echo "***** Missing lua headers ($website) *****"])
 288 AC_SEARCH_LIBS([lua_load], [lua],,
 289                            [missing=yes
 290                                 echo "***** Missing liblua ($website) *****"])
 291
 292 ##### librt (optional) #####
 293 AC_SEARCH_LIBS([clock_gettime], [rt],
 294                            [AC_DEFINE([HAVE_CLOCK_GETTIME], 1,
 295                                                   [Define to 1 if you have the 'clock_gettime' function.])])
 296
 297
 298 if test x$missing == xyes
 299 then
 300         AC_MSG_ERROR([please install missing dependencies (see messages above)])
 301 fi
 302
 303
 304 #
 305 # Find the data files to install.
 306 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 307
 308 DATA_FILES=$(echo $(cd data; \
 309                                         find . -name "*.json" \
 310                                                 -o -name "*.lua" \
 311                                                 -o -name "*.ogg" \
 312                                                 -o -name "*.png" \
 313                                                 -o -name "*.xm" \
 314                                                 -o -name "yoinkrc"))
 315 AC_SUBST([DATA_FILES])
 316
 317
 318 #
 319 # Create the build files.
 320 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 321
 322 AC_CONFIG_FILES([Makefile
 323                                  data/Makefile
 324                                  doc/Makefile
 325                                  doc/yoink.6
 326                                  extra/Makefile
 327                                  extra/yoink.spec
 328                                  make-win32-installer.sh
 329                  src/Makefile])
 330
 331 AC_CONFIG_HEADERS([src/config.h])
 332
 333 AC_OUTPUT
 334
 335
 336 #
 337 # Print a friendly little message.
 338 #~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 339
 340 echo ""
 341 echo " Configuration complete! :-)"
 342 echo ""
 343 echo "          Target: $target"
 344 echo "          Prefix: $prefix"
 345 echo "  Data Directory: $DATADIR"
 346 echo "       Log Level: $log_level"
 347 echo "           Debug: $debug"
 348 echo "         Profile: $profile"
 349 echo "  Extra Warnings: $extra_warnings"
 350 echo ""
 351 echo " To finish the installation, execute:"
 352 echo "  make"
 353 echo "  make install"
 354 echo ""
 355