Dogcows Code - chaz/tar/blob - configure.ac

   1 # Configure template for GNU tar.
   2
   3 # Copyright (C) 1991, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 # 2002, 2003 Free Software Foundation, Inc.
   5
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_INIT([GNU tar], [1.13.26], [bug-tar@gnu.org])
  22 AC_CONFIG_SRCDIR([src/tar.c])
  23 AC_CONFIG_AUX_DIR([config])
  24 AC_CONFIG_HEADERS([config.h:config.hin])
  25 AC_PREREQ([2.57])
  26 AM_INIT_AUTOMAKE([1.7.5 gnits dist-bzip2 dist-shar])
  27
  28 gl_USE_SYSTEM_EXTENSIONS
  29 AC_PROG_CC
  30 AC_EXEEXT
  31 AC_PROG_RANLIB
  32 AC_SYS_LARGEFILE
  33 AC_ISC_POSIX
  34 AC_C_INLINE
  35
  36 AC_CHECK_HEADERS(fcntl.h linux/fd.h memory.h net/errno.h \
  37   sgtty.h string.h \
  38   sys/buf.h sys/device.h sys/gentape.h \
  39   sys/inet.h sys/io/trioctl.h \
  40   sys/mtio.h sys/tprintf.h sys/tape.h \
  41   unistd.h)
  42
  43 AC_HEADER_SYS_WAIT
  44 AM_STDBOOL_H
  45
  46 if test $ac_cv_header_sys_mtio_h = yes; then
  47   AC_CACHE_CHECK(for remote tape header files, tar_cv_header_rmt,
  48     [AC_TRY_CPP([
  49 #if HAVE_SGTTY_H
  50 # include <sgtty.h>
  51 #endif
  52 #include <sys/socket.h>],
  53     tar_cv_header_rmt=yes, tar_cv_header_rmt=no)])
  54   test $tar_cv_header_rmt = yes && RMT='rmt$(EXEEXT)'
  55   AC_SUBST(RMT)
  56 fi
  57
  58 AC_CACHE_CHECK(which ioctl field to test for reversed bytes,
  59   tar_cv_header_mtio_check_field,
  60   [AC_EGREP_HEADER(mt_model, sys/mtio.h,
  61   tar_cv_header_mtio_check_field=mt_model,
  62   tar_cv_header_mtio_check_field=mt_type)])
  63 AC_DEFINE_UNQUOTED(MTIO_CHECK_FIELD, $tar_cv_header_mtio_check_field,
  64   [Define to mt_model (v.g., for DG/UX), else to mt_type.])
  65
  66 AC_HEADER_DIRENT
  67 AC_HEADER_MAJOR
  68 AC_HEADER_STAT
  69 AC_HEADER_STDC
  70 AC_STRUCT_ST_BLKSIZE
  71 AC_STRUCT_ST_BLOCKS
  72 AC_MSG_CHECKING([for st_fstype string in struct stat])
  73 AC_CACHE_VAL(diff_cv_st_fstype_string,
  74   [AC_TRY_COMPILE([#include <sys/types.h>
  75 #include <sys/stat.h>], [struct stat s; s.st_fstype[0] = 'x';],
  76    diff_cv_st_fstype_string=yes,
  77    diff_cv_st_fstype_string=no)])
  78 AC_MSG_RESULT($diff_cv_st_fstype_string)
  79 if test $diff_cv_st_fstype_string = yes; then
  80   AC_DEFINE(HAVE_ST_FSTYPE_STRING, 1,
  81     [Define if struct stat has a char st_fstype[] member.])
  82 fi
  83
  84 AC_TYPE_SIGNAL
  85 AC_TYPE_MODE_T
  86 AC_TYPE_PID_T
  87 AC_TYPE_OFF_T
  88 AC_TYPE_SIZE_T
  89 AC_TYPE_UID_T
  90 AC_CHECK_TYPE(major_t, , AC_DEFINE(major_t, int,
  91                                    [Type of major device numbers.]))
  92 AC_CHECK_TYPE(minor_t, , AC_DEFINE(minor_t, int,
  93                                    [Type of minor device numbers.]))
  94 AC_CHECK_TYPE(dev_t, unsigned)
  95 AC_CHECK_TYPE(ino_t, unsigned)
  96
  97 gt_TYPE_SSIZE_T
  98 jm_AC_TYPE_UINTMAX_T
  99
 100
 101 # gnulib modules
 102
 103 AM_FUNC_GETLINE
 104
 105 gl_BACKUPFILE
 106 gl_DIRNAME
 107 gl_ERROR
 108 gl_EXCLUDE
 109 gl_FILEBLOCKS
 110 gl_FUNC_ALLOCA
 111 gl_FUNC_FNMATCH_GNU
 112 gl_FUNC_MEMSET
 113 gl_FUNC_MKTIME
 114 gl_FUNC_RMDIR
 115 gl_FUNC_STRTOL
 116 gl_FUNC_STRTOUL
 117 gl_GETDATE
 118 gl_GETOPT
 119 gl_HASH
 120 gl_HUMAN
 121 gl_MODECHANGE
 122 gl_OBSTACK
 123 gl_PATHMAX
 124 gl_QUOTE
 125 gl_QUOTEARG
 126 gl_SAFE_READ
 127 gl_SAFE_WRITE
 128 gl_SAVE_CWD
 129 gl_SAVEDIR
 130 gl_STRCASE
 131 gl_XALLOC
 132 gl_XGETCWD
 133 gl_XSTRTOL
 134
 135 jm_FUNC_FTRUNCATE
 136 jm_FUNC_GLIBC_UNLOCKED_IO
 137 jm_FUNC_LCHOWN
 138 jm_FUNC_MALLOC
 139 jm_FUNC_REALLOC
 140 jm_FUNC_UTIME
 141 jm_XSTRTOUMAX
 142
 143
 144 # Save and restore LIBS so e.g., -lrt, isn't added to it.  Otherwise, *all*
 145 # programs in the package would end up linked with that potentially-shared
 146 # library, inducing unnecessary run-time overhead.
 147
 148 # Solaris 2.5.1 needs -lposix4 to get the clock_gettime function.
 149 # Solaris 7 prefers the library name -lrt to the obsolescent name -lposix4.
 150 tar_save_LIBS=$LIBS
 151   LIB_CLOCK_GETTIME=
 152   AC_SEARCH_LIBS(clock_gettime, [rt posix4],
 153                  [LIB_CLOCK_GETTIME=$ac_cv_search_clock_gettime])
 154   AC_SUBST(LIB_CLOCK_GETTIME)
 155   AC_CHECK_FUNCS(clock_gettime)
 156 LIBS=$tar_save_LIBS
 157
 158 AC_CHECK_FUNCS(fsync lstat mkfifo readlink strerror symlink)
 159 AC_CHECK_DECLS([getgrgid],,, [#include <grp.h>])
 160 AC_CHECK_DECLS([getpwuid],,, [#include <pwd.h>])
 161 AC_CHECK_DECLS([valloc])
 162
 163 # Set LIB_SETSOCKOPT to -lnsl -lsocket if necessary.
 164 tar_save_LIBS=$LIBS
 165   LIB_SETSOCKOPT=
 166   AC_SEARCH_LIBS(setsockopt, [socket], ,
 167     [AC_SEARCH_LIBS(setsockopt, [socket], , , [-lnsl])])
 168   AC_SEARCH_LIBS(setsockopt, [nsl])
 169   if test " $LIBS" != " $tar_save_LIBS"; then
 170     LIB_SETSOCKOPT=$ac_cv_search_setsockopt
 171   fi
 172   AC_SUBST(LIB_SETSOCKOPT)
 173 LIBS=$tar_save_LIBS
 174
 175 AC_REPLACE_FUNCS(waitpid)
 176
 177 AC_CACHE_CHECK(for remote shell, tar_cv_path_RSH,
 178   [if test -n "$RSH"; then
 179     tar_cv_path_RSH=$RSH
 180   else
 181     tar_cv_path_RSH=no
 182     for ac_file in /usr/ucb/rsh /usr/bin/remsh /usr/bin/rsh /usr/bsd/rsh \
 183         /usr/bin/nsh /usr/bin/rcmd
 184     do
 185       # Prefer a non-symlink rsh to a symlink one, so that binaries built
 186       # on AIX 4.1.4, where /usr/ucb/rsh is a symlink to /usr/bin/rsh
 187       # will run on AIX 4.3.0, which has only /usr/bin/rsh.
 188       if test -f $ac_file; then
 189         if (test -h $ac_file) 2>/dev/null; then
 190           test $tar_cv_path_RSH = no && tar_cv_path_RSH=$ac_file
 191         else
 192           tar_cv_path_RSH=$ac_file
 193           break
 194         fi
 195       fi
 196     done
 197   fi])
 198 if test $tar_cv_path_RSH = no; then
 199   AC_CHECK_HEADERS(netdb.h)
 200 else
 201   AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$tar_cv_path_RSH",
 202     [Define to the full path of your rsh, if any.])
 203 fi
 204
 205 AC_MSG_CHECKING(for default archive format)
 206
 207 if test -z "$DEFAULT_ARCHIVE_FORMAT"; then
 208   DEFAULT_ARCHIVE_FORMAT="GNU"
 209 fi
 210 case $DEFAULT_ARCHIVE_FORMAT in
 211   V7|OLDGNU|POSIX|GNU) ;;
 212   *) AC_MSG_ERROR(Invalid format name);;
 213 esac
 214 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE_FORMAT, ${DEFAULT_ARCHIVE_FORMAT}_FORMAT,
 215   [By default produce archives of this format])
 216 AC_MSG_RESULT($DEFAULT_ARCHIVE_FORMAT)
 217
 218 AC_MSG_CHECKING(for default archive)
 219
 220 if test -z "$DEFAULT_ARCHIVE"; then
 221   DEFAULT_ARCHIVE=-
 222 else
 223   if test -z "`ls $DEFAULT_ARCHIVE 2>/dev/null`"; then
 224     AC_MSG_WARN(DEFAULT_ARCHIVE \`$DEFAULT_ARCHIVE' not found on this system)
 225   fi
 226   # FIXME: Look for DEFTAPE in <sys/mtio.h>.
 227   # FIXME: Let DEVICE_PREFIX be configured from the environment.
 228   # FIXME: Rearrange, here.
 229   case $DEFAULT_ARCHIVE in
 230     *[[0-7][lmh]])
 231       AC_DEFINE(DENSITY_LETTER, 1,
 232         [[Define to 1 if density may be indicated by [lmh] at end of device.]])
 233       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7][lmh]$//'`
 234       ;;
 235     *[[0-7]])
 236       device_prefix=`echo $DEFAULT_ARCHIVE | sed 's/[0-7]$//'`
 237       ;;
 238     *)
 239       device_prefix=
 240       ;;
 241   esac
 242   case "$device_prefix" in
 243     ?*)
 244       AC_DEFINE_UNQUOTED(DEVICE_PREFIX, "$device_prefix",
 245         [Define to a string giving the prefix of the default device, without the part specifying the unit and density.])
 246       ;;
 247   esac
 248 fi
 249 AC_DEFINE_UNQUOTED(DEFAULT_ARCHIVE, "$DEFAULT_ARCHIVE",
 250   [Define to a string giving the full name of the default archive file.])
 251 AC_MSG_RESULT($DEFAULT_ARCHIVE)
 252
 253 AC_MSG_CHECKING(for default blocking)
 254 DEFAULT_BLOCKING=${DEFAULT_BLOCKING-20}
 255 AC_DEFINE_UNQUOTED(DEFAULT_BLOCKING, $DEFAULT_BLOCKING,
 256   [Define to a number giving the default blocking size for archives.])
 257 AC_MSG_RESULT($DEFAULT_BLOCKING)
 258
 259 # Gettext.
 260 AM_GNU_GETTEXT([external], [need-ngettext])
 261 AM_GNU_GETTEXT_VERSION(0.12.1)
 262
 263 AC_OUTPUT([Makefile doc/Makefile lib/Makefile \
 264 m4/Makefile po/Makefile.in \
 265 scripts/Makefile src/Makefile tests/Makefile tests/preset])