Dogcows Code - chaz/tar/blob - m4/getcwd.m4

   1 # getcwd.m4 - check whether getcwd (NULL, 0) allocates memory for result
   2
   3 # Copyright 2001 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software Foundation,
  17 # Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.  */
  18
  19 # Written by Paul Eggert.
  20
  21 AC_DEFUN([AC_FUNC_GETCWD_NULL],
  22   [AC_CHECK_HEADERS(stdlib.h unistd.h)
  23    AC_CACHE_CHECK([whether getcwd (NULL, 0) allocates memory for result],
  24      [ac_cv_func_getcwd_null],
  25      [AC_TRY_RUN(
  26         [
  27 #        ifdef HAVE_STDLIB_H
  28 #         include <stdlib.h>
  29 #        endif
  30 #        ifdef HAVE_UNISTD_H
  31 #         include <unistd.h>
  32 #        endif
  33 #        ifndef getcwd
  34          char *getcwd ();
  35 #        endif
  36          int
  37          main ()
  38          {
  39            if (chdir ("/") != 0)
  40              exit (1);
  41            else
  42              {
  43                char *f = getcwd (NULL, 0);
  44                exit (! (f && f[0] == '/' && !f[1]));
  45              }
  46          }],
  47         [ac_cv_func_getcwd_null=yes],
  48         [ac_cv_func_getcwd_null=no],
  49         [ac_cv_func_getcwd_null=no])])
  50    if test $ac_cv_func_getcwd_null = yes; then
  51      AC_DEFINE(HAVE_GETCWD_NULL, 1,
  52                [Define if getcwd (NULL, 0) allocates memory for result.])
  53    fi])