From be56b6d1620e61c2b9b655a9925f8b0ba1c3c3b8 Mon Sep 17 00:00:00 2001
From: Dana Jansens <danakj@orodu.net>
Date: Sat, 11 Jan 2003 02:10:55 +0000
Subject: [PATCH] create OB_DEBUG and OB_COMPILER_FLAGS m4 functionc

---
 m4/openbox.m4 | 65 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 m4/openbox.m4

diff --git a/m4/openbox.m4 b/m4/openbox.m4
new file mode 100644
index 00000000..cd76bb63
--- /dev/null
+++ b/m4/openbox.m4
@@ -0,0 +1,65 @@
+# OB_DEBUG()
+#
+# Check if the user has requested a debug build.
+# Sets the DEBUG or NDEBUG variables as appropriate
+AC_DEFUN([OB_DEBUG],
+[
+  DEBUG="no"
+  AC_MSG_CHECKING([build target type])
+
+  AC_ARG_ENABLE([debug],
+  [  --enable-debug          build a debug version default=no],
+  [DEBUG=$enableval],[])
+  if test "$DEBUG" = "yes"; then
+    AC_MSG_RESULT([debug])
+    AC_DEFINE([DEBUG], [1], [Creating a debug build])
+  else
+    AC_MSG_RESULT([release])
+    AC_DEFINE([NDEBUG], [1], [Creating a release build])
+  fi
+])
+
+
+# OB_COMPILER_FLAGS()
+#
+# Check what compiler is being used for compilation.
+# It sets the CXXFLAGS variable appropriately for the compiler, including flags
+# for debug builds.
+AC_DEFUN([OB_COMPILER_FLAGS],
+[
+  AC_REQUIRE([AC_PROG_CXXCPP])
+  AC_REQUIRE([AC_PROG_CXX])
+
+  FLAGS=""
+
+  # Check what compiler we are using
+  AC_MSG_CHECKING([for GNU C++])
+  if test "$GXX" = "yes"; then
+    AC_MSG_RESULT([yes])
+    FLAGS="-Wall -W"
+    # -pedantic
+    test "$DEBUG" = "yes" && FLAGS="$FLAGS -g -fno-inline"
+  else
+    AC_MSG_RESULT([no, trying other compilers])
+    AC_MSG_CHECKING(for MIPSpro)
+    mips_pro_ver=`$CXX -version 2>&1 | grep -i mipspro | cut -f4 -d ' '`
+    if test -z "$mips_pro_ver"; then
+      AC_MSG_RESULT([no])
+    else
+      AC_MSG_RESULT([yes, version $mips_pro_ver.])
+      AC_MSG_CHECKING(for -LANG:std in CXXFLAGS)
+      lang_std_not_set=`echo $CXXFLAGS | grep "\-LANG:std"`
+      if test "x$lang_std_not_set" = "x"; then
+        AC_MSG_RESULT([not set, setting.])
+        FLAGS="-LANG:std"
+      else
+        AC_MSG_RESULT([already set.])
+      fi
+    fi
+  fi
+  AC_MSG_CHECKING([for compiler specific flags])
+  AC_MSG_RESULT([$FLAGS])
+  CXXFLAGS="$CXXFLAGS $FLAGS"
+])
+
+
-- 
2.45.2